******************************************************************************
* feyn_wh_lvbb_example.kumac
* --------------------------
* Author: Leslie Groer		21 April 1998
*
* This is an example KUMAC to produce a Feynman diagram using the PAW FEYN
* package.
*
* The diagram produced here is of associated production of a Higgs boson
* via qq annihilation (q qbar -> W* -> WH) with the W decaying
* to a lepton and neutrino and the Higgs decaying to a b bbar pair.  
* The W is colored blue, the leptons green, the Higgs red
* and the b bbar magenta.
*
* No warranty expressed, implied or even hinted at in the functioning of this
* product.
******************************************************************************
* Setup new drawing area
new 11 10
* Execute the drawing
exec higgsdraw

* Store the plot as a PS and a EPS file
le feyn_wh_lvbb_example
p feyn_wh_lvbb_example
RETURN

*-----------------------------------------------------------------------------
MACRO higgsdraw
* Execute the FEYN drawing commands
*-----------------------------------------------------------------------------
set chhe 0.5
set lwid 5       | default is 3

start 1 3
* Draw qbar line
go 2 2 
ferm -1
text 'q&^[-]!' -2 -0.2 0
* Draw q line
go -2 2
ferm -1
text 'q' 2 +0.2 0
back
* Draw W^*
go 2.8 0
color blue
photon 
text 'W^*!' 1 0 0.5
* Draw H0 branch
go 2 -2 
color red
scal 1
text 'H^o!' -1 0 -0.5  
* Draw b
go 1 1
color magenta 
ferm 1
text 'b' 2 
* Draw bbar
back 1
go 1 -1
color magenta
ferm -1
text 'b&^[-]!' 2
* Draw W branch
* W/Z branch
back 4
go 2 2 
color blue
photon 1
text 'W' 1 0 0.5
* Draw lepton
go 1 -1
color green
ferm 1
text 'l' 2 0 -0.5
* Draw anti-neutrino
color green
back 1
go 1 1
ferm -1
text '[n]!&^[-]!' 2 0 0.2
color black
RETURN